Contoh Menambah Elemen Array (Preserve) VB6

Berikut ini adalah contoh menambah elemen suatu array dengan menggunakan statement "Preserve" di visual basic 6, untuk mempraktekannya siapkan : 

1. Buat 1 Project baru dengan 1 Form dan 2 Commandbutton

2. Copy-kan coding berikut ke dalam editor form yang bertalian.

          'Setiap kali Anda mengeksekusi statement "ReDim", semua nilai dari elemen
          'array yang ada akan dihapus. Visual Basic mengeset ulang nilainya menjadi
          'kosong (untuk array Variant), ke nol (untuk array numeric), ke string
          'dengan panjang nol (untuk array string), atau ke Nothing (untuk arrays
          'of objects).

          'Hal ini sangat berguna ketika Anda ingin menyiapkan array ke data yang baru,
          'atau ketika Anda ingin mengurangi ukuran array untuk menghemat memory.

          'Kadang-kadang, Anda mungkin ingin mengubah ukuran array tanpa harus
          'kehilangan data di array tersebut. Anda dapat melakukan hal ini dengan
          'menggunakan ReDim dengan kata kunci Preserve. Sebagai contoh, Anda dapat
          'memperbesar ukuran sebuah array dengan menambahkan satu elemen tanpa harus
          'kehilangan nilai dari elemen array yang sudah ada, dengan menggunakan

          'fungsi UBound untuk mengacu kepada indeks teratas array tersebut.:

          Private Sub Command1_Click()
          Dim i As Integer

            Dim DynArray() 'Deklarasi array dinamik bernama DynArray
            ReDim DynArray(3) 'Deklarasi ulang sebanyak 4 elemen
           
            'Isi setiap elemen array, dan tampilkan

            For i = 0 To 2
              DynArray(i) = i
              MsgBox DynArray(i)
            Next i
           

            'Tambahkan 1 elemen ke DynArray
            ReDim Preserve DynArray(UBound(DynArray) + 1)
           
            'Isi elemen indeks ke-3 dengan 3

            DynArray(3) = 3
           
            'Tampilkan seluruh elemen setelah ditambah
            For i = 0 To 3

              MsgBox DynArray(i)
            Next i
          End Sub

          'Hanya batas teratas dari dimensi terakhir dalam sebuah array multidimensional

          'yang dapat diganti ketika Anda menggunakan kata kunci Preserve keyword ini;
          'Jika Anda mengubah elemen dimensi lainnya, atau indeks yang lebih rendah dari
          'dimensi yang terakhir, sebuah error saat run-time akan terjadi.
          'Jadi, Anda dapat menggunakan coding seperti ini:

          Private Sub Command2_Click()
          Dim i As Integer, j As Integer
            Dim Matrix() As String 'Deklarasikan array dinamik Matrix
            ReDim Matrix(2, 3) As String 'Deklarasi Matrix sebagai

                                         'array Multidimensi
            'Isi elemen array Matrix...
            Matrix(1, 1) = "Baris satu kolom satu"
            Matrix(1, 2) = "Baris satu kolom dua"

            Matrix(1, 3) = "Baris satu kolom tiga"
            Matrix(2, 1) = "Baris dua kolom satu"
            Matrix(2, 2) = "Baris dua kolom dua"
            Matrix(2, 3) = "Baris dua kolom tiga"

             
            'Tampilkan semua elemen array Matrix
            For i = 1 To 2
              For j = 1 To 3  'Mula-mula masih 3...
                MsgBox Matrix(i, j)

              Next j
            Next i
            
            'Tambahkan satu elemen di dimensi yang terakhir (kanan)

            ReDim Preserve Matrix(2, UBound(Matrix, 2) + 1)
            'Tapi, Anda tidak dapat menggunakan coding berikut:
            'ReDim Preserve Matrix(UBound(Matrix, 1) + 1, 10)
            'karena akan menyebabkan error pada saat run-time

           
            'Sekarang, array ini menjadi Matrix(2, 4)
            'Isi nilai elemen yang ditambahkan ini
            Matrix(1, 4) = "Baris satu kolom empat (baru)"
            Matrix(2, 4) = "Baris dua kolom empat (baru)"


            'Tampilkan semua elemen array Matrix
            For i = 1 To 2
              For j = 1 To 4  'Sekarang sudah menjadi 4...

                MsgBox Matrix(i, j)
              Next j
            Next i
          End Sub

Tags:

contoh program vb6, contoh fungsi di vb6, cara penggunaan fungsi vb, tutorial vb6, download tutorial vb6, vb6 tutorial download, dasar dasar vb6, belajar vb6, cara mudah belajar vb6, vb6 artikel download, vb6 blog, contoh program vb6, artikel vb6, semua tentang vb6, vb6 api, cara menggunakan module, cara menggunakan class module